# shortcut to this dotfiles path is $ZSH
export ZSH=$HOME/dotfiles
#
# # your project folder that we can `c [tab]` to
export PROJECTS=~/projects
# #
# # # all of our zsh files
typeset -U config_files
config_files=($ZSH/**/*.zsh)

# load the path files
for file in ${(M)config_files:#*/path.zsh}
do
	source $file
done

# load everything but the path and completion files
for file in ${${config_files:#*/path.zsh}:#*/completion.zsh}
do
	source $file
done

# use .localrc for SUPER SECRET CRAP that you don't
# want in your public, versioned repo.
if [[ -a ~/.localrc ]]
then
	 source ~/.localrc
fi

# initialize autocomplete here, otherwise functions won't be loaded
autoload -U compinit
compinit
# load every completion after autocomplete loads
for file in ${(M)config_files:#*/completion.zsh}
do
	source $file
done

unset config_files


# autoload -U compinit promptinit
# compinit
# promptinit
# prompt pws

# zstyle ':completion:*' menu select
# zstyle ':completion:*' completer _expand _complete _ignored _correct _approximate
# zstyle :cominstall filename '/home/yorick/.zsh'

ZSH_HIGHLIGHT_HIGHLIGHTERS=(main brackets pattern)
source /usr/share/zsh/plugins/zsh-syntax-highlighting/zsh-syntax-highlighting.zsh